home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / F-French / (c)f1.d64 / tondeuse (.txt) < prev   
Commodore BASIC  |  2007-02-04  |  5KB  |  142 lines
  1. 1 REM LAWN MOWER
  2. 100 VC=53248:POKEVC+32,13:POKEVC+33,6:PRINTCHR$(147)
  3. 110 DIMMT$(4),ST%(20,1)
  4. 120 FORX=0TO20:FORY=0TO1:READZ:ST%(X,Y)=Z:NEXTY,X
  5. 130 FORX=0TO4:READX$:MT$(X)=X$:NEXTX
  6. 140 MC=54272:FORX=MCTO54296:POKEX,0:NEXTX
  7. 150 GOSUB4000
  8. 155 PRINT"  TON PERE TE PRETE $15 POUR QUE TU"
  9. 160 PRINT"  PUISSE OFFRIR UN SERVICE DE TONTE       DE PELOUSE DURANT L ETE."
  10. 165 PRINT" A LA FIN DE L ETE, TU DOIS REMBOURSER"
  11. 170 PRINT" LES $15 A TON PERE."
  12. 175 PRINT" TU ES PAYE $5 PAR TONTE,MAIS TU DOIS"
  13. 180 PRINT" DEDUIRE DE TON REVENU LES DEPENSES"
  14. 185 PRINT" ENCOURUES, COMME:"
  15. 190 PRINT"     LA GASOLINE POUR LA TONDEUSE;"
  16. 193 PRINT"     L'HUILE POUR LA TONDEUSE;"
  17. 196 PRINT"     LES SACS POUR RAMASSER L'HERBE;"
  18. 200 PRINT"     L'AIGUISAGE DE LA LAME."
  19. 210 GOSUB1000:GOSUB1100
  20. 220 PRINT"[147] SI VOUS MANQUEZ DE MATERIEL DURANT LE"
  21. 225 PRINT" MOIS, OU SI VOTRE LAME DE TONDEUSE NE"
  22. 230 PRINT" COUPE PLUS DU A UN MANQUE D'AIGUISAGE"
  23. 235 PRINT" D'AIGUISAGE, TU PERDS TON REVENU POUR"
  24. 240 PRINT" LE RESTE DU MOIS."
  25. 245 PRINT"   LE BUT DU JEU EST D'ACHETER TON"
  26. 250 PRINT"   MATERIEL DE FACON EFFICACE POUR"
  27. 255 PRINT"   QUETU PUISSE GAGNER LE PLUS"
  28. 260 PRINT"   POSSIBLE DURANT L'ETE."
  29. 270 GOSUB1100:POKEVC+33,15:PRINT"";CHR$(147)
  30. 300 MO=1500:GA=0:OA=0:BA=0:SA=0
  31. 310 FORL1=0TO4:LM=0:MM=0
  32. 320 X=INT(RND(1)*71)+80:D1$="GAZ":D2$="LITRES":GOSUB1200
  33. 330 IFY=0THEN350
  34. 340 GA=GA+(Y*100):MO=MO-(X*Y)
  35. 350 X=INT(RND(1)*51)+90:D1$="HUILE":D2$="PINTE":GOSUB1200
  36. 360 IF Y=0THEN380
  37. 370 OA=OA+(Y*100):MO=MO-(X*Y)
  38. 380 X=INT(RND(1)*151)+200:D1$="SACS D'HERBE":D2$="DOUZAINE":GOSUB1200
  39. 390 IFY=0THEN410
  40. 400 BA=BA+(Y*12):MO=MO-(X*Y)
  41. 410 X=INT(RND(1)*201)+400:GOSUB1300:PRINT"[147]        MOIS  = ";MT$(L1)
  42. 420 PRINT"        VEUX TU FAIRE AIGUISER"
  43. 422 PRINT"        LA LAME DE LA TONDEUSE?"
  44. 425 PRINT"        COUT  = ";X$
  45. 430 PRINT"        INDIQUER O[146] OU N[146]"
  46. 440 GETX$:IFX$=""THEN440
  47. 450 IF X$="N"THEN500
  48. 460 IF X$<>"O"THEN440
  49. 470 MO=MO-X
  50. 480 X=INT(RND(1)*21)+20:SA=SA+X
  51. 500 GC=INT(RND(1)*51)+20:OC=INT(RND(1)*31)+10
  52. 510 BC=INT(RND(1)*4)+1
  53. 520 IF MO<0THENGC=GC*2:OC=OC*2:BC=BC*2
  54. 530 X=1:IF(GA-GC)<0THEN700
  55. 540 X=2:IF(OA-OC)<0THEN700
  56. 550 X=3:IF(BA-BC)<0THEN700
  57. 560 X=4:IF(SA-1)<0THEN700
  58. 570 GA=GA-GC:OA=OA-OC:BA=BA-BC:SA=SA-1
  59. 580 LM=LM+1:MM=MM+500
  60. 600 PRINT"[147]        ";MT$(L1):PRINT"        PELOUSE NUMERO   ";LM
  61. 610 X=MM:GOSUB1300:PRINT"        ARGENT GAGNE    = ";X$
  62. 620 PRINT"        GAZ RESTANT     =";INT((GA+100)/100)
  63. 625 PRINT"        HUILE RESTANT   =";INT((OA+100)/100)
  64. 630 PRINT"        SACS RESTANT    =";BA
  65. 640 FORX=2TO10STEP2:GOSUB660:NEXTX
  66. 650 FORX=10TO0STEP-2:GOSUB660:NEXTX:GOTO500
  67. 660 POKEMC+0,0:POKEMC+1,10:POKEMC+5,15:POKEMC+6,15:POKEMC+7,0:POKEMC+8,0
  68. 670 POKEMC+11,15:POKEMC+12,15
  69. 675 POKEMC+24,X:POKEMC+8,40:POKEMC+4,129:POKEMC+10,17
  70. 680 FORY=1TO100:NEXTY
  71. 685 POKEMC+4,128:POKEMC+10,16
  72. 690 FORY=1TO20:NEXTY
  73. 695 RETURN
  74. 700 POKEMC+0,0:POKEMC+1,25:POKEMC+7,0:POKEMC+8,0:POKEMC+5,15:POKEMC+6,15
  75. 710 POKEMC+24,9:POKEMC+4,33:FORY=1TO500:NEXTY
  76. 715 POKEMC+4,32:FORY=1TO20:NEXTY:POKEMC+24,0:PRINTCHR$(147);
  77. 718 PRINT""
  78. 720 ONXGOTO730,740,750,760
  79. 730 PRINT"        PANNE D'ESSENCE![146]":GOTO770
  80. 740 PRINT"        PANNE D'HUILE![146]":GOTO770
  81. 750 PRINT"        MANQUE DE SACS[146]":GOTO770
  82. 760 PRINT"        LA LAME NE COUPE PLUS![146]"
  83. 770 PRINT"        PELOUSE TONDUE  = ";LM
  84. 780 X=MM:GOSUB1300
  85. 785 PRINT"        ARGENT GAGNE    =  ";X$
  86. 790 MO=MO+MM:X=MO:GOSUB1300:PRINT"        REVENU BRUT     =  ";X$
  87. 795 GOSUB1100:NEXTL1
  88. 800 PRINT"[147]";SPC(14);"ETE TERMINE![146]":X=MO:GOSUB1300
  89. 805 PRINT"        ARGENT EN MAIN = ";X$
  90. 810 X=1500:GOSUB1300:PRINT"        MOINS EMPRUNT  = ";X$
  91. 820 MO=MO-1500:X=MO:GOSUB1300:PRINT"        REVENU NET     = ";X$
  92. 830 PRINT"             AUTRE PARTIE? (O[146] OU N[146])"
  93. 840 GETX$:IFX$=""THEN840
  94. 850 IF X$="O"THEN300
  95. 860 IF X$<>"N"THEN840
  96. 870 PRINTCHR$(147)
  97. 880 END
  98. 1000 POKEMC+24,15:POKEVC+21,1
  99. 1005 FORX=0TO20:TT$=RIGHT$(TT$,LEN(TT$)-2):TT$=TT$+"  "
  100. 1010 PRINT"";TT$;
  101. 1015 Y=INT(ST%(X,0)/256)
  102. 1020 POKEMC+0,ST%(X,0)-(Y*256)
  103. 1025 POKEMC+1,Y:POKEMC+4,17
  104. 1030 Y=PEEK(VC+0)-14
  105. 1035 IFY<1THENY=255:POKEVC+0,Y:POKEVC+16,0
  106. 1040 POKEVC+0,Y
  107. 1045 FORY=1TOST%(X,1)*60:NEXTY
  108. 1050 POKEMC+4,16:FORY=1TO30:NEXTY,X
  109. 1055 POKEMC+24,0:POKEVC+21,0
  110. 1060 PRINT"";SPC(15);"TONDEUSE[146]";
  111. 1070 RETURN
  112. 1100 PRINT"            (PRESSER UNE TOUCHE)";
  113. 1110 GETX$:IFX$=""THEN1110
  114. 1120 RETURN
  115. 1200 PRINT"[147]        MOIS  = ";MT$(L1):GOSUB1300
  116. 1210 PRINT"        ITEM  = ";D1$:PRINT"        COUT  = ";X$;" PAR ";D2$
  117. 1220 PRINT"        COMBIEN EN VOULEZ VOUS?"
  118. 1225 PRINT"        IMDIQUER DE 0[146] A 9[146]"
  119. 1230 GETD1$:IF D1$=""THEN1230
  120. 1240 IFD1$<"0"ORD1$>"9"THEN1230
  121. 1250 Y=VAL(D1$):RETURN
  122. 1300 X$=STR$(X):Z=LEN(X$)
  123. 1310 IFZ<3THENX$=LEFT$(X$,1)+"$0.0"+RIGHT$(X$,1):GOTO1370
  124. 1320 IFZ<4THENX$=LEFT$(X$,1)+"$0."+RIGHT$(X$,2):GOTO1370
  125. 1330 Z=Z-3:X$=LEFT$(X$,1)+"$"+MID$(X$,2,Z)+"."+RIGHT$(X$,2)
  126. 1370 IFLEFT$(X$,1)=" "THENX$=RIGHT$(X$,LEN(X$)-1):GOTO1370
  127. 1380 RETURN
  128. 3000 DATA8583,2,4291,2,4291,2,5407,1,5728,2,10814,2,10814,2,9634,2
  129. 3010 DATA8583,1,7217,2,8583,2,4291,2,4291,2,5407,2,6430,2,6430,2
  130. 3020 DATA 6430,2,7217,2,8101,2,8101,2,8583,2
  131. 3100 DATAMAI,JUIN,JUILLET,AOUT,SEPTEMBRE
  132. 3200 DATA0,0,0,0,0,0,0,0,0,0,0,0,0,3,128,0,7,128,0,3,128,0,1,0,0,3
  133. 3210 DATA128,0,3,128,0,31,128,0,35,128,0,67,128,0,131,128
  134. 3220 DATA1,3,128,2,3,128,4,2,64,8,4,32,80,8,16,224,4,8,80,2,4,0
  135. 4000 REM *** SETUP FOR SPRITE ***
  136. 4010 FORX=832TO832+63:READZ:POKEX,Z:NEXTX
  137. 4020 POKEVC+0,60:POKEVC+1,55:POKEVC+16,1:POKEVC+23,1:POKEVC+28,0
  138. 4030 POKEVC+29,1:POKEVC+39,0:POKE2040,13
  139. 4040 POKEMC+0,0:POKEMC+1,0:POKEMC+5,79:POKEMC+6,129
  140. 4050 TT$="                        TONDEUSE"
  141. 4060 RETURN
  142.